# $Id: PKGBUILD 237386 2015-04-18 09:43:07Z andyrtr $
# Maintainer: Andreas Radke <andyrtr@archlinux.org>
# Contributor: spider-mario <spidermario@free.fr>
# Contributor: Daniel Ehlers <danielehlers@mindeye.net>

pkgname=coin-or-mp
pkgver=1.8.1
pkgrel=1
pkgdesc="C-API library that supports most of the functionality of CLP (Coin LP), CBC (Coin Branch-and-Cut), and CGL (Cut Generation Library) projects"
arch=('i686' 'x86_64')
url="https://projects.coin-or.org/CoinMP"
license=('EPL')
groups=('coin-or')
depends=('coin-or-cbc')
provides=('coin-mp')
options=('!emptydirs')
source=(http://www.coin-or.org/download/source/CoinMP/CoinMP-$pkgver.tgz)
sha256sums=('2be92d64a515d9cf0194c1cda4e1ec0b55512f88ce5a7cf1254ffc89e20608d7')

build() {
  cd CoinMP-$pkgver
  COIN_SKIP_PROJECTS="Sample" \
  ./configure --prefix=/usr \
              --with-osi-lib="$(pkg-config --libs osi)" \
              --with-osi-incdir="/usr/include/coin/" \
              --with-clp-lib="$(pkg-config --libs clp)" \
              --with-clp-incdir="/usr/include/coin/" \
              --with-cgl-lib="$(pkg-config --libs cgl)" \
              --with-cgl-incdir="/usr/include/coin/" \
              --with-cbc-lib="$(pkg-config --libs cbc)" \
              --with-cbc-incdir="/usr/include/coin/" \
              --with-coinutils-lib="$(pkg-config --libs coinutils)" \
              --with-coinutils-incdir="/usr/include/coin/"
  make
}

check() {
  cd CoinMP-$pkgver
  make test
}

package() {
  cd CoinMP-$pkgver/CoinMP
  PKG_CONFIG_LIBDIR="$pkgdir"/usr/lib/pkgconfig/ \

  make DESTDIR="$pkgdir" install
  mv "$pkgdir/$pkgdir"/usr/share/coin/doc/CoinMP/* "$pkgdir"/usr/share/coin/doc/CoinMP/
}

