# $Id: PKGBUILD 123379 2014-12-03 10:10:57Z arodseth $
# Maintainer: Alexander Rødseth <rodseth@gmail.com>
# Contributor: Thomas Dziedzic < gostrc at gmail >
# Contributor: Chris Baker <baker.chris.3@gmail.com>

pkgbase=python-nltk
pkgname=('python2-nltk' 'python-nltk')
pkgver=3.0.0
pkgrel=1
pkgdesc='Natural language processing in Python'
arch=('any')
url='http://www.nltk.org/'
license=('APACHE')
makedepends=('python-setuptools' 'python2-setuptools')
source=("git+https://github.com/nltk/nltk#tag=$pkgver")
md5sums=('SKIP')

prepare() {
  cp -r nltk nltk-py2
  # python 2 fix
  cd nltk-py2
  find . -type f -exec sed -i 's:^#.*env python:#!/usr/bin/env python2:' {} +
}

build() {
  cd nltk
  python setup.py build
  cd "$srcdir/nltk-py2"
  python2 setup.py build
}

package_python-nltk() {
  optdepends=('nltk-data: test data'
              'python-numpy: used for calculations'
              'python-matplotlib: used for plotting')
  depends=('python-yaml')

  cd nltk
  python setup.py install --root="$pkgdir" --optimize=1
}

package_python2-nltk() {
  optdepends=('nltk-data: test data'
              'python2-numpy: used for calculations'
              'python2-matplotlib: used for plotting')
  depends=('python2-yaml')

  cd nltk-py2
  python2 setup.py install --root="$pkgdir" --optimize=1
}

# vim:set ts=2 sw=2 et:
