# $Id: PKGBUILD 128968 2015-03-09 09:08:19Z mtorromeo $
# Maintainer: Massimiliano Torromeo <massimiliano.torromeo@gmail.com>
# Contributor: D. Can Celasun <dcelasun[at]gmail[dot]com>
# Contributor: Felix Hanley <felix@seconddrawer.com.au>
# Contributor: Sławomir Kowalski <suawekk@gmail.com>

pkgname=percona-toolkit
pkgver=2.2.13
pkgrel=1
pkgdesc="Collection of advanced command-line tools to perform a variety of MySQL and system tasks."
url="http://www.percona.com/software/percona-toolkit/"
arch=('any')
license=('GPL')
depends=('perl-term-readkey')
makedepends=('perl-dbd-mysql' 'perl-dbi')
optdepends=(
    'perl-dbd-mysql: MySQL connections'
    'perl-dbi: MySQL connections'
)
options=('!emptydirs' 'purge')
source=("http://www.percona.com/downloads/$pkgname/$pkgver/tarball/$pkgname-$pkgver.tar.gz")
sha256sums=('8e69f619d163cd7afa22bd1cf144df0f6d08f06c7559510a73467db1eeff4a63')

build() {
    cd "$srcdir"/$pkgname-$pkgver
    unset PERL5LIB PERL_MM_OPT PERL_LOCAL_LIB_ROOT
    export PERL_MM_USE_DEFAULT=1 PERL_AUTOINSTALL=--skipdeps MODULEBUILDRC=/dev/null
    perl Makefile.PL
    make
}

package() {
    cd "$srcdir"/$pkgname-$pkgver
    unset PERL5LIB PERL_MM_OPT PERL_LOCAL_LIB_ROOT
    make install INSTALLDIRS=vendor DESTDIR="$pkgdir"
}
