# $Id: PKGBUILD 108290 2014-03-26 09:45:53Z svenstaro $
# Maintainer: Sven-Hendrik Haase <sh@lutzhaase.com>
# Contributor: Jschares <jacob.schares@gmail.com>
# Contributor: celmir <scibecelmir@tuxfamily.org>
# Contributor: Feufochmar <guill.delacourt@gmail.com>

pkgname=paintown
pkgver=3.6.0
pkgrel=3
pkgdesc="Open source fighting game in the same genre as Streets of Rage and Teenage Mutant Ninja Turtles"
arch=('i686' 'x86_64')
url="http://paintown.sourceforge.net/"
license=('GPL')
depends=('python2' 'freetype2' 'sdl' 'libpng' 'mpg123' 'libogg' 'libvorbis')
makedepends=('cmake')
#install=paintown.install
source=(http://downloads.sourceforge.net/sourceforge/paintown/$pkgname-$pkgver.tar.bz2)
md5sums=('5c1160bee51fe2011a1141c490a5d368')

prepare() {
  cd "$pkgname-$pkgver"

  # fix python2 header
  for file in $(find . -name '*.py' -print); do
     sed -i "s#/usr/bin/python#/usr/bin/env python2#" $file
  done

  sed -i "s/find_package(FREETYPE)/find_package(Freetype)/g" CMakeLists.txt
}

build() {
  cd "$pkgname-$pkgver"

  mkdir -p build && cd build
  cmake -DFREETYPE_INCLUDE_DIR=/usr/include/freetype2 ..
  make
  cp bin/paintown ..
}

package() {
  cd "$srcdir/$pkgname-$pkgver"
  mkdir -p $pkgdir/usr/{bin,share/{paintown,pixmaps,applications,licenses/paintown}}
  sh install.sh -d $pkgdir/usr/share/paintown -b $pkgdir/usr/bin
  # correct the gnerated file to remove the wrong path (because $pkgdir/usr/bin is written in the file)
  sed -i "s#$pkgdir##g" $pkgdir/usr/bin/paintown
  install -m644 misc/paintown.desktop $pkgdir/usr/share/applications/paintown.desktop
  install -m644 misc/logo-256x256.png $pkgdir/usr/share/pixmaps/paintown.png
  install -m644 LICENSE $pkgdir/usr/share/licenses/$pkgname/LICENSE
  install -m644 LEGAL $pkgdir/usr/share/licenses/$pkgname/LEGAL
}

# vim:set ts=2 sw=2 et:
