# $Id$
# Maintainer: Alexandre Filgueria <alexfilgueira@antergos.com>
# Contributor:  Jan de Groot <jan@archlinux.org>

pkgname=cinnamon-desktop
pkgver=2.4.2
pkgrel=1
pkgdesc="Library with common API for various Cinnamon modules"
arch=(i686 x86_64)
license=(GPL LGPL)
depends=(gtk3 libxkbfile python2)
makedepends=(intltool gobject-introspection gnome-common python2)
url="https://github.com/linuxmint/cinnamon-desktop"
install=cinnamon-desktop.install
source=("${pkgname}-${pkgver}.tar.gz::https://github.com/linuxmint/cinnamon-desktop/archive/${pkgver}.tar.gz"
        "gnome-3.14.patch")
sha256sums=('62e2ff4fad405f8d4e7259dbeb2daf65c6f8b9995f2bb1e595a7cc0c2a7f9e0a'
            'c4df93c49fd3f9f8bc359cbad5d5526eef80ee5c34680f8ba62c67c3dbb7eca5')

prepare() {
  cd $pkgname-$pkgver
  # Update configuration for GNOME 3.14
  patch -Np1 -i ../gnome-3.14.patch
}

build() {
  cd $pkgname-$pkgver
  ./autogen.sh --prefix=/usr --sysconfdir=/etc --localstatedir=/var \
    --libexecdir=/usr/lib/$pkgname --disable-static
  make
}

package() {
  cd $pkgname-$pkgver
  make DESTDIR="$pkgdir" install
}
