# $Id: PKGBUILD 130947 2015-04-08 16:59:20Z spupykin $
# Maintainer: Sergej Pupykin <pupykin.s+arch@gmail.com>
# Contributor: Daniel Micay <danielmicay@gmail.com>
# Contributor: Bartłomiej Piotrowski <nospam@bpiotrowski.pl>
# Contributor: Patrick Leslie Polzer <leslie.polzer@gmx.net>
# Contributor: cdhotfire <cdhotfire@gmail.com>
# Contributor: Shinlun Hsieh <yngwiexx@yahoo.com.tw>
# Contributor: Elisamuel Resto <ryuji@simplysam.us>

pkgname=chrony
pkgver=1.31.1
pkgrel=1
pkgdesc='Lightweight NTP client and server'
arch=('i686' 'x86_64')
url="http://chrony.tuxfamily.org/"
options=(strip emptydirs)
license=('GPL')
depends=('nss' 'readline' 'libcap')
backup=('etc/chrony.conf')
source=(http://download.tuxfamily.org/chrony/${pkgname}-${pkgver}.tar.gz
        service)
install=${pkgname}.install
sha256sums=('43aca956a0beb2c4847feffc847fec2c429ee9afb6252c7a499bbd68933046dd'
            'dbd30435d5f51a92ecef779efa0eabaf56d09a35a18ddd30644d5418beada212')
sha256sums=('a35e1cae46ecbe14af2023bb47a72a03d79591b2ff65f0072b3400153224996d'
            'dbd30435d5f51a92ecef779efa0eabaf56d09a35a18ddd30644d5418beada212')
sha256sums=('0ba9f4b58e20b2eaae921eb8c798108ef72d8ea6fdcc7eb0167b56690d212348'
            'dbd30435d5f51a92ecef779efa0eabaf56d09a35a18ddd30644d5418beada212')

prepare() {
  cd $pkgname-$pkgver
  sed -i 's|.pool.ntp.org|.arch.pool.ntp.org|g' examples/chrony.conf.example
}

build() {
  cd $pkgname-$pkgver
  ./configure --prefix=/usr
  make
}

package() {
  cd $pkgname-$pkgver
  make DESTDIR="$pkgdir" install install-docs

  install -Dm0644 "$srcdir/$pkgname-$pkgver/examples/chrony.conf.example" "$pkgdir/etc/chrony.conf"

  echo -e "\n# Enable kernel RTC sync\nrtcsync" >> "$pkgdir/etc/chrony.conf"

  sed -i '/^! rtconutc$/ s/^! //' "$pkgdir/etc/chrony.conf"

  mv "$pkgdir/usr/sbin/chronyd" "$pkgdir/usr/bin"
  rmdir "$pkgdir/usr/sbin"

  install -Dm644 "$srcdir/service" "$pkgdir/usr/lib/systemd/system/chrony.service"

  chown 183:183 "$pkgdir/var/lib/chrony"
}
