# $Id: PKGBUILD 129959 2015-03-26 13:35:02Z svenstaro $
# Maintainer: Sven-Hendrik Haase <sh@lutzhaase.com>
# Contributor: Bartłomiej Piotrowski <bpiotrowski@archlinux.org>
# Contributor: Daniel Wallace <danielwallace at gtmanfred dot com>
# Contributor: Chris <seitz.christoph@gmail.com>
# Contributor: m0ikz <ndelatorre@moikz.com.ar>
# Contributor: atweiden <archbaum@gmail.com>

pkgname=ansible
pkgver=1.9.0.1
pkgrel=1
pkgdesc='Radically simple IT automation platform'
arch=('any')
url='http://www.ansible.com'
license=('GPL3')
depends=('python2' 'python2-yaml' 'python2-paramiko' 'python2-jinja')
makedepends=('asciidoc' 'fakeroot')
backup=('etc/ansible/ansible.cfg')
source=(http://releases.ansible.com/ansible/$pkgname-$pkgver.tar.gz)
md5sums=('3773b0df98288c237f2329cf184ff59f')

build() {
  cd $pkgname-$pkgver
  python2 setup.py build
}

package() {
  cd $pkgname-$pkgver
  python2 setup.py install -O1 --root="$pkgdir"
  install -Dm644 COPYING "$pkgdir"/usr/share/doc/ansible/COPYING

  install -d "$pkgdir"/usr/share/ansible/doc
  cp -dpr --no-preserve=ownership ./examples "$pkgdir"/usr/share/ansible/doc/
  install -Dm644 examples/ansible.cfg "$pkgdir"/etc/ansible/ansible.cfg

  install -d "$pkgdir"/usr/share/man/man1
  cp -dpr --no-preserve=ownership docs/man/man1/*.1 "$pkgdir"/usr/share/man/man1
}
