# $Id: PKGBUILD 108130 2014-03-23 13:52:23Z arodseth $
# Maintainer: Alexander Rødseth <rodseth@gmail.com>
# Contributor: tdy <tdy@gmx.com>
# Contributor: nut543 <kfs1@online.no>

pkgname=vor
pkgver=0.5.5
pkgrel=3
pkgdesc='Classic spaceship versus asteroid field arcade game'
arch=('x86_64' 'i686')
url='http://jasonwoof.org/vor'
license=('GPL')
depends=('sdl_image' 'sdl_mixer')
makedepends=('gendesk')
optdepends=('netpbm: for customizing game graphics'
            'povray: for customizing game graphics')
options=('!emptydirs')
source=("http://qualdan.com/$pkgname/$pkgname-$pkgver.tar.bz2"
        "$pkgname.png")
sha256sums=('ead1b9786741e26d37ff7c5185b7fe1e91f90f76ebed3785225312e323b7c7da'
            '07a805928f5cf2b3351e2b9ff820ea69352ad80faad43311889ffbd5f62da872')

prepare() {
  gendesk -f --pkgname "$pkgname" --pkgdesc "$pkgdesc"
}

build() {
  cd "$pkgname-$pkgver"
  ./configure --prefix=/usr
  make LDFLAGS=-lm
}

package() {
  install -d "$pkgdir/usr/bin"
  make -C "$pkgname-$pkgver" prefix=/usr DESTDIR="$pkgdir" install
  install -Dm644 "$pkgname.png" "$pkgdir/usr/share/pixmaps/$pkgname.png"
  install -Dm644 "$pkgname.desktop" \
    "$pkgdir/usr/share/applications/$pkgname.desktop"
}

# vim:set ts=2 sw=2 et:
