# $Id: PKGBUILD 129094 2015-03-12 08:11:44Z alucryd $
# Maintainer: Maxime Gauduin <alucryd@archlinux.org>
# Contributor: Gustavo Alvarez <sl1pkn07@gmail.com>

pkgname=vapoursynth-plugin-mvtools
pkgver=8
pkgrel=1
pkgdesc='MVTools plugin for VapourSynth'
arch=('i686' 'x86_64')
url='https://github.com/dubhater/vapoursynth-mvtools'
license=('GPL2')
depends=('fftw' 'vapoursynth')
makedepends=('yasm')
source=("vapoursynth-plugin-mvtools-${pkgver}.tar.gz::https://github.com/dubhater/vapoursynth-mvtools/archive/v${pkgver}.tar.gz")
sha256sums=('b933d6c849aaa96f14c09592a77503e6cc2680d642b97c7841a2c95745b330e6')

build() {
  cd vapoursynth-mvtools-${pkgver}

  ./autogen.sh
  ./configure \
    --prefix='/usr' \
    --libdir='/usr/lib/vapoursynth'
  make
}

package(){
  cd vapoursynth-mvtools-${pkgver}

  make DESTDIR="${pkgdir}" install
  install -dm 755 "${pkgdir}"/usr/share/doc/vapoursynth/plugins/MVTools
  install -m 644 readme.rst "${pkgdir}"/usr/share/doc/vapoursynth/plugins/MVTools/README
}

#vim: ts=2 sw=2 et:
