# $Id: PKGBUILD 129571 2015-03-19 12:39:36Z jlichtblau $
# Maintainer: Martin Wimpress <code@flexion.org>
# Maintainer: Jaroslav Lichtblau <svetlemodry@archlinux.org>
# Contributor: kozec <kozec at kozec dot com>

pkgname=syncthing-gtk
pkgver=0.6.3
pkgrel=1
pkgdesc='GTK3 based GUI and notification area icon for Syncthing'
arch=('any')
url='https://github.com/syncthing/syncthing-gtk'
license=('GPL2')
depends=('gtk3' 'libnotify' 'python2-dateutil' 'python2-gobject' 'python2-pyinotify' 'python2-cairo' 'syncthing')
makedepends=('python2-setuptools')
optdepends=('python2-nautilus: file manager integration for Nautilus'
            'python2-caja: file manager integration for Caja'
            'librsvg: to shown menu icons correctly if not using traditional window header')
source=($pkgname-$pkgver.tar.gz::https://github.com/syncthing/$pkgname/archive/v$pkgver.tar.gz)
sha256sums=('56a52cdfd6a8a381a5c2cdd954895849bdc1832a507bb136d3a627ee6883f920')

build() {
  cd $pkgname-$pkgver
  python2 setup.py build
}

package() {
  cd $pkgname-$pkgver
  python2 setup.py install --root="${pkgdir}" --optimize=1
}
