# $Id: PKGBUILD 130230 2015-03-30 03:44:09Z fyan $
# Maintainer: Felix Yan <felixonmars@archlinux.org>
# Contributor: Roger Duran <rogerduran@gmail.com>

pkgbase=python-xcffib
pkgname=(python-xcffib python2-xcffib)
pkgver=0.2.2
pkgrel=1
pkgdesc="Python3 drop in replacement for xpyb, an XCB python binding"
arch=('i686' 'x86_64')
url="https://pypi.python.org/pypi/xcffib"
license=('Apache')
makedepends=('python-setuptools' 'python2-setuptools' 'python-cffi' 'python2-cffi'
             'python-six' 'python2-six' 'libxcb')
source=("https://pypi.python.org/packages/source/x/xcffib/xcffib-$pkgver.tar.gz")
md5sums=('b398d5c6d8b190848c45287715da1383')

prepare() {
  cp -a xcffib-$pkgver{,-py2}
}

package_python-xcffib() {
  depends=('python-six' 'python-cffi' 'libxcb')

  cd "$srcdir/xcffib-$pkgver"
  python setup.py install --root="$pkgdir/" --optimize=1
}

package_python2-xcffib() {
  depends=('python2-six' 'python2-cffi' 'libxcb')

  cd "$srcdir/xcffib-$pkgver-py2"
  python2 setup.py install --root="$pkgdir/" --optimize=1
}
