# $Id: PKGBUILD 125381 2015-01-05 03:48:44Z fyan $
# Maintainer: Felix Yan <felixonmars@archlinux.org>

pkgbase=python-sparqlwrapper
pkgname=("python-sparqlwrapper" "python2-sparqlwrapper")
pkgver=1.6.4
pkgrel=1
pkgdesc="SPARQL Endpoint interface to Python"
arch=('any')
url="http://rdflib.github.io/sparqlwrapper/"
license=('W3C')
makedepends=('python-setuptools' 'python2-setuptools')
source=("https://pypi.python.org/packages/source/S/SPARQLWrapper/SPARQLWrapper-$pkgver.tar.gz")
md5sums=('e30a18bd53e16c93e5fc0a2cc736ad34')

prepare() {
  cp -a SPARQLWrapper-$pkgver{,-py2}
}

package_python-sparqlwrapper() {
  depends=('python3')

  cd SPARQLWrapper-$pkgver
  LC_CTYPE=en_US.utf8 python3 setup.py install --root="${pkgdir}" --optimize=1
  #install -Dm644 LICENSE "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
}

package_python2-sparqlwrapper() {
  depends=('python2')

  cd SPARQLWrapper-$pkgver-py2
  python2 setup.py install --root="${pkgdir}" --optimize=1
  #install -Dm644 LICENSE "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
}

