# $Id: PKGBUILD 130035 2015-03-27 15:13:49Z aginiewicz $
# Maintainer: Andrzej Giniewicz <gginiu@gmail.com>
# Contributor: Sebastien Binet <binet@cern.ch>

pkgbase=python-pytables
pkgname=('python2-pytables' 'python-pytables')
pkgver=3.1.1
pkgrel=5
arch=("i686" "x86_64")
pkgdesc="A package for managing hierarchical datasets and designed to efficiently and easily cope with extremely large amounts of data"
url="http://www.pytables.org"
license=("BSD")
makedepends=('lzo' 'hdf5' 'python2-numexpr' 'cython2' 'python-numexpr' 'cython')
source=("http://pypi.python.org/packages/source/t/tables/tables-$pkgver.tar.gz"
        "cython-0.21.patch")
md5sums=('38d917f0c6dfb0bc28ce9ea0c3492524'
         'c224fd77ddc69027955898a16a4766a9')

prepare() {
  cd "$srcdir"/tables-$pkgver
  patch -p1 < ../cython-0.21.patch

  cd "$srcdir"
  cp -a tables-$pkgver tables-py2-$pkgver
}

build() {
  msg "Building Python2"
  cd "$srcdir"/tables-py2-$pkgver
  python2 setup.py build

  msg "Building Python3"
  cd "$srcdir"/tables-$pkgver
  python setup.py build
}

package_python2-pytables() {
  depends=('lzo' 'hdf5' 'python2-numexpr' 'cython2')

  cd "$srcdir"/tables-py2-${pkgver}
  python2 setup.py install --prefix=/usr --root="$pkgdir" --optimize=1

  install -Dm644 LICENSE.txt "$pkgdir/usr/share/licenses/$pkgname/LICENSE"

  # see FS#36015
  mv "$pkgdir"/usr/bin/pt2to3{,-2.7}
  mv "$pkgdir"/usr/bin/ptdump{,-2.7}
  mv "$pkgdir"/usr/bin/ptrepack{,-2.7}
}

package_python-pytables() {
  depends=('lzo' 'hdf5' 'python-numexpr' 'cython')

  cd "$srcdir"/tables-${pkgver}
  python setup.py install --prefix=/usr --root="$pkgdir" --optimize=1

  install -Dm644 LICENSE.txt "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
}

