# $Id: PKGBUILD 122641 2014-11-16 12:14:06Z fyan $
# Maintainer: Felix Yan <felixonmars@archlinux.org>

pkgbase=opencc
pkgname=(opencc opencc-doc)
pkgver=1.0.2
pkgrel=1
url="http://code.google.com/p/opencc/"
arch=('i686' 'x86_64')
license=('Apache')
makedepends=('cmake' 'doxygen' 'python')
source=("https://github.com/BYVoid/OpenCC/archive/ver.${pkgver}.tar.gz")
sha512sums=('e8ed5662c4ac37bb8df7e80fc3da3fb101af0232cd68313e1d8c83b1247d5583b660557878dc441b18d7751393ef1a696bec4d9c4dc7328e4d8668d0c5525c1d')

build() {
  cd OpenCC-ver.${pkgver}
  cmake -DCMAKE_INSTALL_PREFIX=/usr -DCMAKE_BUILD_TYPE=Release -DBUILD_DOCUMENTATION:BOOL=ON
  make
}

package_opencc() {
  pkgdesc="Library for Open Chinese Convert"
  depends=('gcc-libs')

  cd OpenCC-ver.${pkgver}
  make DESTDIR="${pkgdir}" install
  
  # Remove docs - install in splitted package
  rm -r "$pkgdir/usr/share/opencc/doc"
}

package_opencc-doc() {
  pkgdesc="Documentation for Library for Open Chinese Convert"

  cd OpenCC-ver.${pkgver}/doc
  make DESTDIR="${pkgdir}" install
}

