# $Id: PKGBUILD 121592 2014-10-30 04:25:39Z eric $
# Maintainer: Federico Cinelli <cinelli@aur.archlinux.org>

pkgname=nss-pam-ldapd
pkgver=0.9.4
pkgrel=1
pkgdesc='LDAP module for NSS and PAM'
arch=('i686' 'x86_64')
url="http://arthurdejong.org/nss-pam-ldapd/"
license=('LGPL2.1')
depends=('pam')
conflicts=('pam_ldap')
backup=('etc/nslcd.conf')
options=('!emptydirs')
install=nss-pam-ldapd.install
source=("http://arthurdejong.org/$pkgname/$pkgname-$pkgver.tar.gz"
        "nslcd.service"
        "nslcd.tmpfiles")
md5sums=('0d74202700efdde3b6e551bfff49c132'
         'c2edd35bab384c907eb442c606de856f'
         'd78a702ae9e81af03ae0a85a6af4d2f3')

build() {
  cd "$srcdir/$pkgname-$pkgver"
  ./configure \
    --prefix=/usr \
    --sbindir=/usr/bin \
    --sysconfdir=/etc \
    --localstatedir=/var \
    --with-pam-seclib-dir=/usr/lib/security

  make
}

package() {
  cd "$srcdir/$pkgname-$pkgver"

  install -Dm644 "$srcdir/nslcd.tmpfiles" "$pkgdir/usr/lib/tmpfiles.d/nslcd.conf"
  install -Dm644 "$srcdir/nslcd.service" "$pkgdir/usr/lib/systemd/system/nslcd.service"
  install -Dm644 "$srcdir/$pkgname-$pkgver/nslcd.conf" "$pkgdir/etc/nslcd.conf"

  make DESTDIR="$pkgdir" install
}

# vim:set ts=2 sw=2 et:
