# $Id: PKGBUILD 118660 2014-09-08 13:27:03Z spupykin $
# Maintainer: Sergej Pupykin <pupykin.s+arch@gmail.com>
# Maintainer : SpepS <dreamspepser at yahoo dot it>
# Contributor: Auguste <auguste@gmail.com>
# Contributor: Jose Negron <josenj.arch@mailnull.com>

pkgname=libharu
pkgver=2.3.0
pkgrel=1
pkgdesc="C library for generating PDF documents"
url="https://github.com/libharu/libharu"
arch=('i686' 'x86_64')
license=('custom:ZLIB')
depends=('libpng' 'gcc-libs')
source=("https://github.com/libharu/libharu/archive/RELEASE_${pkgver//./_}.tar.gz")
md5sums=('4f916aa49c3069b3a10850013c507460')

build() {
  cd "$srcdir/$pkgname-RELEASE_${pkgver//./_}"
  touch include/config.h.in
  aclocal
  libtoolize
  automake --add-missing
  autoconf
  ./configure --prefix=/usr
  make
}

package() {
  cd "$srcdir/$pkgname-RELEASE_${pkgver//./_}"
  make DESTDIR="$pkgdir/" install
  # license
  install -d "$pkgdir/usr/share/licenses/$pkgname"
  sed -n '102,120p' README > "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
}
