# $Id: PKGBUILD 124741 2014-12-28 11:20:57Z fyan $
# Maintainer: Felix Yan <felixonmars@archlinux.org>
# Contributor: Thomas Dziedzic < gostrc at gmail >
# Contributor: Rainy <rainylau(at)gmail(dot)com>
# Contributor: Lee.MaRS <leemars@gmail.com>
# Contributor: Hiroshi Yui <hiroshiyui@gmail.com>

pkgname=ibus-chewing
pkgver=1.4.14
_cmakefedoraver=2.3.4
pkgrel=1
pkgdesc='Chinese Chewing Engine for IBus Framework'
arch=('i686' 'x86_64')
license=('GPL')
url='http://ibus.googlecode.com'
depends=('ibus' 'libchewing' 'libxtst' 'gconf')
makedepends=('swig' 'gob2' 'cmake' 'git')
install=ibus-chewing.install
source=("git+https://github.com/definite/ibus-chewing.git#tag=$pkgver"
        "git+http://git.fedorahosted.org/git/cmake-fedora.git#tag=$_cmakefedoraver")
sha512sums=('SKIP'
            'SKIP')

prepare() {
  cd $pkgname
  ln -s ../cmake-fedora/Modules ./
}

build() {
  cd $pkgname
  cmake . -DCMAKE_INSTALL_PREFIX=/usr \
    -DSYSCONF_INSTALL_DIR=/usr/share \
    -DLIBEXEC_DIR=/usr/lib/ibus
  make
  make translations
}

package() {
  cd $pkgname
  make DESTDIR="$pkgdir" install
}
