# $Id: PKGBUILD 124371 2014-12-22 22:13:47Z bisson $
# Maintainer: Jaroslav Lichtblau <dragonlord@aur.archlinux.org>
# Maintainer: Gaetan Bisson <bisson@archlinux.org>
# Contributor: Jeff Mickey <jeff@archlinux.org>
# Contributor: Grigorios Bouzakis <grbzks@gmail.com>

pkgname=fdm
pkgver=1.8
pkgrel=1
pkgdesc='Program to fetch and deliver mail'
url='http://fdm.sourceforge.net/'
license=('BSD')
arch=('i686' 'x86_64')
depends=('openssl' 'tdb' 'zlib')
source=("http://downloads.sourceforge.net/project/${pkgname}/${pkgname}/${pkgname}-${pkgver}/${pkgname}-${pkgver}.tar.gz")
sha1sums=('25c0ebc0c2b43984d04c82d0ba3909acf7403df7')

options=('!makeflags')

build() {
	cd "${srcdir}/${pkgname}-${pkgver}"
	./configure
	make PREFIX=/usr MANDIR=/usr/share/man
}

package() {
	cd "${srcdir}/${pkgname}-${pkgver}"

	make DESTDIR="${pkgdir}" PREFIX=/usr MANDIR=/usr/share/man install

	install -d "${pkgdir}/usr/share/licenses/${pkgname}"
	sed '3,17p;d' fdm.c > "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"

	install -d "${pkgdir}/usr/share/doc/${pkgname}"
	cp -a examples "${pkgdir}/usr/share/doc/${pkgname}"
}
