# $Id: PKGBUILD 128939 2015-03-08 18:59:54Z bgyorgy $
# Maintainer: Balló György <ballogyor+arch at gmail dot com>
# Contributor: Bartłomiej Piotrowski
# Contributor: Brad Fanella <bradfanella@archlinux.us>
# Contributor: Allan McRae <allan@archlinux.org>
# Contributor: Tomas A. Schertel <tschertel@gmail.com>

pkgname=cherrytree
pkgver=0.35.7
pkgrel=1
pkgdesc='Hierarchical note taking application featuring rich text and syntax highlighting'
arch=('any')
url='http://www.giuspen.com/cherrytree/'
license=('GPL3')
depends=('pygtksourceview2' 'python2-dbus' 'desktop-file-utils')
optdepends=('python2-pyenchant: for spell checking support'
            'p7zip: for password protection support')
install=cherrytree.install
source=(http://www.giuspen.com/software/$pkgname-$pkgver.tar.xz)
sha256sums=('e311af09fe634dcd8d2934a9bbc8eed546a01ca8b02b006b0e66b0a94f5fe30e')

build() {
  cd $pkgname-$pkgver
  python2 setup.py build
}

package() {
  cd $pkgname-$pkgver
  python2 setup.py install --root="$pkgdir/" --optimize=1

  # Fix file permissions
  find "$pkgdir/usr/share" -type f | xargs chmod 644
}
