# $Id: PKGBUILD 210526 2014-04-14 20:07:25Z jgc $
# Maintainer: Ionut Biru <ibiru@archlinux.org>

pkgbase=pyatspi
pkgname=(python-atspi python2-atspi)
pkgver=2.12.0
pkgrel=1
arch=(any)
url="http://www.linuxfoundation.org/en/AT-SPI_on_D-Bus"
license=('GPL2')
makedepends=(python-gobject python2-gobject at-spi2-core)
source=(http://download.gnome.org/sources/${pkgbase}/${pkgver:0:4}/${pkgbase}-${pkgver}.tar.xz)
sha256sums=('4e6cd801412a090dcc7ec2a27298dee5e84dc0af11479d5d5c061254b8ea6ac4')

build() {
  mkdir python2 python3

  cd $pkgbase-$pkgver
  sed '/AC_PATH_XTRA/d' -i configure.ac
  autoreconf -fi

  cd ../python2
  ../$pkgbase-$pkgver/configure --prefix=/usr --with-python=/usr/bin/python2
  make

  cd ../python3
  ../$pkgbase-$pkgver/configure --prefix=/usr --with-python=/usr/bin/python
  make
}

package_python-atspi() {
  pkgdesc="Python 3 bindings for at-spi"
  depends=(python-gobject at-spi2-core)

  cd python3
  make DESTDIR="$pkgdir" install
}

package_python2-atspi() {
  pkgdesc="Python 2 bindings for at-spi"
  depends=(python2-gobject at-spi2-core)
  provides=("pyatspi=$pkgver")
  replaces=(pyatspi)
  conflicts=(pyatspi)

  cd python2
  make DESTDIR="$pkgdir" install
}

# vim:set ts=2 sw=2 et:
