# $Id: PKGBUILD 225969 2014-11-10 23:27:14Z heftig $
# Maintainer: Jan Alexander Steffens (heftig) <jan.steffens@gmail.com>
# Contributor: Jan de Groot <jgc@archlinux.org>

pkgname=gnome-sudoku
pkgver=3.14.2
pkgrel=1
pkgdesc="Test your logic skills in this number grid puzzle"
arch=('x86_64' 'i686')
license=('GPL')
depends=('hicolor-icon-theme' 'dconf' 'gtk3' 'qqwing' 'libgee' 'json-glib')
makedepends=('intltool' 'itstool' 'vala')
conflicts=('gnome-games')
replaces=('gnome-games')
options=('!emptydirs')
install=gnome-sudoku.install
url="https://live.gnome.org/GnomeSudoku"
groups=('gnome-extra')
source=(http://ftp.gnome.org/pub/gnome/sources/$pkgname/${pkgver:0:4}/$pkgname-$pkgver.tar.xz)
sha256sums=('4364662b624d76e174f1930811061de5358c917e4f546c8e5ca234e120689301')

build() {
  cd $pkgname-$pkgver
  ./configure --prefix=/usr --sysconfdir=/etc \
      --localstatedir=/var --disable-schemas-compile
  make
}

package() {
  cd $pkgname-$pkgver
  make DESTDIR="$pkgdir" install

  sed -i 's_#! /usr/bin/python_#!/usr/bin/python2_' "$pkgdir/usr/bin/gnome-sudoku"
}
