# $Id: PKGBUILD 220869 2014-09-01 14:30:51Z giovanni $
# Maintainer: Giovanni Scafora <giovanni@archlinux.org> 
# Contributor: Biru Ionut <ionut@archlinux.ro>
# Contributor: Eric Belanger <eric@archlinux.org>
# Contributor: Aurelien Foret <orelien@chez.com>

pkgname=libtar
pkgver=1.2.20
pkgrel=2
pkgdesc="C library for manipulating POSIX tar files"
arch=('i686' 'x86_64')
url="http://repo.or.cz/w/libtar.git/"
license=('BSD')
depends=('zlib')
source=("http://pkgbuild.com/~giovanni/${pkgname}/${pkgname}-${pkgver}.tar.gz")
md5sums=('c8507795b3d461ed10566a61fb4cad9b')

prepare() {
  cd "${srcdir}/${pkgname}"

  sed -i \
      -e '/INSTALL_PROGRAM/s:-s::' {doc,lib{,tar}}/Makefile.in
}

build() {
  cd "${srcdir}/${pkgname}"
  export CFLAGS+=" -fPIC"

  autoreconf -fi
  ./configure --prefix=/usr \
              --mandir=/usr/share/man \
              --disable-static \
              --disable-encap \
              --disable-epkg-install
  make
}

package() {
  cd "${srcdir}/${pkgname}"

  make DESTDIR="${pkgdir}" install
  install -D -m644 COPYRIGHT "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
}
