# $Id: PKGBUILD 222710 2014-09-22 19:58:25Z heftig $
# Maintainer: Pierre Schmitz <pierre@archlinux.de>

pkgbase=ca-certificates
pkgname=(ca-certificates-utils ca-certificates)
pkgver=20140325
pkgrel=2
pkgdesc='Common CA certificates'
arch=('any')
url='http://packages.qa.debian.org/c/ca-certificates.html'
license=('MPL' 'GPL')
depends=('bash' 'run-parts' 'openssl' 'findutils' 'coreutils' 'sed')
makedepends=('python2')
source=("http://ftp.debian.org/debian/pool/main/c/${pkgbase}/${pkgbase}_${pkgver}.tar.xz"
	confd.patch)
sha256sums=('c0e3d8c517995db2737f7f1a9b69d654b8823fa6d337871c6ce111fcf083454a'
            '6a6efe688bd7f40dc57d07ad6bfdbb83f4853a1964c55e0620e833e6c2945dab')

prepare() {
	cd "${srcdir}/${pkgbase}"
	patch -Np1 -i ../confd.patch
}

package_ca-certificates-utils() {
	pkgdesc+=" (utilities)"
	backup=('etc/ca-certificates.conf')
	install=ca-certificates-utils.install
	provides=(ca-certificates)

	cd "${srcdir}/${pkgbase}"

	install -d "${pkgdir}"/{etc/{ca-certificates/update.d,ssl/certs},usr/share/ca-certificates}
	install -Dm644 sbin/update-ca-certificates.8 "${pkgdir}/usr/share/man/man8/update-ca-certificates.8"
	install -D sbin/update-ca-certificates "${pkgdir}/usr/bin/update-ca-certificates"
}

package_ca-certificates() {
	pkgdesc+=" (default providers)"
	depends=(ca-certificates-{mozilla,cacert})
}

# vim:set noet ts=8 sw=8:
