# Zsh (日本語)

Zsh は対話式シェルとしてもスクリプト言語のインタプリタとしても使えるパワフルなシェルです。Bash と互換性がありながら (デフォルトではありません、"emulate sh" を実行した時だけです)、Zsh には多くの利点があります:

- 高速
- 高度なタブ補完
- 高度なグロブ
- 高度な行列処理
- 完全にカスタマイズ可能

Zsh FAQ には他にも Zsh をあなたのシェルとして使うべき 理由 が列挙されています。

## インストール

インストールをする前に現在使っているシェルが何なのか知っておくとよいでしょう:

    $ echo $SHELL

公式リポジトリにある zsh パッケージをインストールしてください。

### 初期設定

ターミナルで次のコマンドを実行して Zsh が正しくインストールされたか確認してください:

    $ zsh

基本的な設定を説明する zsh-newuser-install が表示されるはずです。これをスキップしたい場合、`q` を押して下さい。手動で呼び出すには:

    $ zsh /usr/share/zsh/functions/Newuser/zsh-newuser-install -f

### Zsh をデフォルトのシェルにする

シェルが `/etc/shells` に記載されていれば、`chsh` コマンドを使って root 権限なしでデフォルトシェルを変更することができます。公式リポジトリから Zsh をインストールしたのなら、既に `/etc/shells` にエントリが作られているはずです。

現在使っているユーザーのデフォルトシェルを変更するには:

    $ chsh -s $(which zsh)

Note: Zsh をデフォルトシェルとして起動するには、一度ログアウトしてからログインしなおす必要があります。

最ログイン後、Bash とは見た目が異なる Zsh のプロンプトが表示されていることに気づくでしょう。また、次のコマンドを実行することで Zsh が現在のシェルになっていることを確認できます:

    $ echo $SHELL

Tip: bash を置き換える場合、`~/.bashrc` から `~/.zshrc` に (例: プロンプトとエイリアス) また `~/.bash_profile` から `~/.zprofile` に (例: X Window System を起動するコード) にコードを移動するとよいでしょう。

## 設定ファイル

ログイン時、Zsh は以下のファイルをこの順番で読み込みます:

`~/.zshenv`
  このファイルにはコマンドの検索パスを設定するコマンドや、重要な環境変数を含めます; 出力をするコマンドや tty に基づいているコマンドを含めてはいけません。
`/etc/profile`
  このファイルはログイン時に Bourne 互換シェルによって読み込まれます: ログイン時やアプリケーション固有の設定 `/etc/profile.d/*.sh`) を設定します。
`~/.zprofile`
  このファイルは一般的にユーザーのスクリプトを自動で実行するために使われます。
`~/.zshrc`
  これは Zsh のメインの設定ファイルです。
`~/.zlogin`
  このファイルは一般的にユーザーのスクリプトを自動で実行するために使われます。

ログアウト時には `~/.zlogout` が読み込まれます。このファイルはユーザーのスクリプトを自動で実行するために使われます。

Note:

- Arch の zsh パッケージで使われているパスは man ページで使われているデフォルトのパスとは異なっています。
- `$ZDOTDIR` のデフォルトは `$HOME` です
- `/etc/profile` は Zsh のスタートアップファイルの標準リストに含まれていませんが、zsh パッケージに入っている `/etc/zsh/zprofile` から読み込まれます。`/etc/profile` で `$PATH` 変数を設定すると `~/.zshenv` に設定した `$PATH` 変数を全て上書きしてしまうので注意してください。これを防ぐには、`/etc/zsh/zprofile` をあなたの作ったファイルに置き換えるか、`~/.zshrc` から `$PATH` 変数を設定してください。

## ~/.zshrc の設定

Zsh は何も設定しなくても使うことができますが、あなたが使いたい機能はほとんど設定されていないでしょう。ただし Zsh で利用できるカスタム化の道は険しく、Zsh の設定は困難をきわめ多くの時間を浪費するかもしれません。

### grml-zsh-config

車輪の再発明をしたくないユーザーは grml-zsh-config をインストールすることが推奨されています。Arch Live CD では初めからインストールされています。このパッケージを使うと zsh の多くの機能がデフォルトで有効になります。

### シンプルな .zshrc

下にはサンプルの設定ファイルが含まれており、Zsh のカスタマイズの方法の例だけでなくデフォルトオプションのセットも提供しています。この設定を使うには `.zshrc` という名前でファイルを保存してください。ログインしなおさなくても次を実行することで変更を適用できます:

    $ source ~/.zshrc

以下はシンプルな `.zshrc` です、基点としてはピッタリでしょう:

    ~/.zshrc

    autoload -U compinit promptinit
    compinit
    promptinit

    # This will set the default prompt to the walters theme
    prompt walters

### $PATH の設定

zsh でユーザーごとにシステムパスを設定する方法についての情報はここにあります: http://zsh.sourceforge.net/Guide/zshguide02.html#l24

以下を `~/.zshenv` に追加してください:

    ~/.zshenv

    typeset -U path
    path=(~/bin /other/things/in/path $path)

### コマンド補完

Zsh の一番魅力的な機能はおそらく先進的な自動補完機能でしょう。少なくとも、`.zshrc` で自動補完を有効にしたいと思うはずです。自動補完を有効にするには、以下を追加してください:

    ~/.zshrc

    autoload -U compinit
    compinit

この設定は ssh/scp/sftp のホスト名の補完も含んでいますが、この機能を動かすには `~/.ssh/known_hosts` で ssh がホスト名をハッシュ化しないようにする必要があります。

Warning: ハッシュ化を解除すると "Island-hopping" 攻撃 に無防備になります。そのことを前もって知った上で、次の行をコメントアウトするか値を `no` に設定してください:

    /etc/ssh/ssh_config

    #HashKnownHosts yes

これで `~/.ssh/known_hosts` をどこか他のところに移動すれば ssh はハッシュ化されてないホスト名を使って新しいファイルを作成します (以前のホストは消失します)。詳細については、hashed-hosts に関する SSH の readme を見て下さい。

矢印キーのインターフェイスを使って自動補完するには、以下を追加して下さい:

    ~/.zshrc

    zstyle ':completion:*' menu select

  メニューを有効にするには、タブを二度押して下さい。

エイリアスでコマンドラインの自動補完を切り替えるには、以下を追加して下さい:

    ~/.zshrc

    setopt completealiases

### "command not found" フック

Pkgfile/"Command not found" フック を見て下さい。

### 履歴に同じ行が重複するのを避ける

履歴の重複する行を無視するととても便利です。これをするには、以下を追加して下さい:

    ~/.zshrc

    setopt HIST_IGNORE_DUPS

### キーバインド

Zsh は readline を使っていません、代わりに自身のパワフルな zle を使っています。zle は `/etc/inputrc` や `~/.inputrc` を読みません。 zle には emacs モードと vi モードがあります。デフォルトでは、`$EDITOR` 環境変数から emacs と vi どちらのキーをあなたが使いたいのか考えます。この変数が空の場合、デフォルトは emacs モードです。 `bindkey -v` や `bindkey -e` でモードを変更することが可能です。

特殊なキーを動作させるには:

    ~/.zshrc

    # create a zkbd compatible hash;
    # to add other keys to this hash, see: man 5 terminfo
    typeset -A key

    key[Home]=${terminfo[khome]}

    key[End]=${terminfo[kend]}
    key[Insert]=${terminfo[kich1]}
    key[Delete]=${terminfo[kdch1]}
    key[Up]=${terminfo[kcuu1]}
    key[Down]=${terminfo[kcud1]}
    key[Left]=${terminfo[kcub1]}
    key[Right]=${terminfo[kcuf1]}
    key[PageUp]=${terminfo[kpp]}
    key[PageDown]=${terminfo[knp]}

    # setup key accordingly
    [[ -n "${key[Home]}"     ]]  && bindkey  "${key[Home]}"     beginning-of-line
    [[ -n "${key[End]}"      ]]  && bindkey  "${key[End]}"      end-of-line
    [[ -n "${key[Insert]}"   ]]  && bindkey  "${key[Insert]}"   overwrite-mode
    [[ -n "${key[Delete]}"   ]]  && bindkey  "${key[Delete]}"   delete-char
    [[ -n "${key[Up]}"       ]]  && bindkey  "${key[Up]}"       up-line-or-history
    [[ -n "${key[Down]}"     ]]  && bindkey  "${key[Down]}"     down-line-or-history
    [[ -n "${key[Left]}"     ]]  && bindkey  "${key[Left]}"     backward-char
    [[ -n "${key[Right]}"    ]]  && bindkey  "${key[Right]}"    forward-char
    [[ -n "${key[PageUp]}"   ]]  && bindkey  "${key[PageUp]}"   beginning-of-buffer-or-history
    [[ -n "${key[PageDown]}" ]]  && bindkey  "${key[PageDown]}" end-of-buffer-or-history

    # Finally, make sure the terminal is in application mode, when zle is
    # active. Only then are the values from $terminfo valid.
    if (( ${+terminfo[smkx]} )) && (( ${+terminfo[rmkx]} )); then
        function zle-line-init () {
            printf '%s' "${terminfo[smkx]}"
        }
        function zle-line-finish () {
            printf '%s' "${terminfo[rmkx]}"
        }
        zle -N zle-line-init
        zle -N zle-line-finish
    fi

Note: To get the proper sequences for certain key combinations, start `cat` or `read` without any parameters and press them; they should then be printed in the terminal. Both can be closed again via `Ctrl+c`.

#### terminfo を使わない方法

`autoload zkbd` を実行してから `zkbd` を実行して下さい。キーを押せない場合は (例: `F11` はウィンドウを最大化します)、スペースを押してスキップして下さい。zkbd が完了した後、以下を `~/.zshrc` に追加して下さい:

    ~/.zshrc

    autoload zkbd
    source ~/.zkbd/$TERM-:0.0 # may be different - check where zkbd saved yours

    [[ -n ${key[Backspace]} ]] && bindkey "${key[Backspace]}" backward-delete-char
    [[ -n ${key[Insert]} ]] && bindkey "${key[Insert]}" overwrite-mode
    [[ -n ${key[Home]} ]] && bindkey "${key[Home]}" beginning-of-line
    [[ -n ${key[PageUp]} ]] && bindkey "${key[PageUp]}" up-line-or-history
    [[ -n ${key[Delete]} ]] && bindkey "${key[Delete]}" delete-char
    [[ -n ${key[End]} ]] && bindkey "${key[End]}" end-of-line
    [[ -n ${key[PageDown]} ]] && bindkey "${key[PageDown]}" down-line-or-history
    [[ -n ${key[Up]} ]] && bindkey "${key[Up]}" up-line-or-search
    [[ -n ${key[Left]} ]] && bindkey "${key[Left]}" backward-char
    [[ -n ${key[Down]} ]] && bindkey "${key[Down]}" down-line-or-search
    [[ -n ${key[Right]} ]] && bindkey "${key[Right]}" forward-char

#### ncurses アプリケーションのキーバインド

ncurses アプリケーションをキーストロークにバインドすることが可能ですが、対話はできません。`BUFFER` 変数を使って動作させて下さい。以下の例は `Alt+\` で ncmpcpp を開きます:

    ~/.zshrc

    ncmpcppShow() { BUFFER="ncmpcpp"; zle accept-line; }
    zle -N ncmpcppShow
    bindkey '^[\' ncmpcppShow

### 履歴検索

以下の行を .zshrc に追加して下さい:

    ~/.zshrc

    [[ -n "${key[PageUp]}"   ]]  && bindkey  "${key[PageUp]}"    history-beginning-search-backward
    [[ -n "${key[PageDown]}" ]]  && bindkey  "${key[PageDown]}"  history-beginning-search-forward

これを設定すると、現在の入力で始まる過去のコマンドだけが表示されるようになります。

### プロンプト

Zsh には手軽にカラープロンプトを設定する方法があります。`.zshrc` でプロンプトが自動ロードされるように設定してください。以下の行を追加することで自動ロードされます:

    ~/.zshrc

    autoload -U promptinit
    promptinit

次のコマンドを実行することで利用可能なプロンプトを見ることができます:

    $ prompt -l

表示されたコマンドの一つを試すには、prompt コマンドの後に使いたいプロンプトの名前を加えて下さい。例えば、`walters` プロンプトを使うには、次のように入力します:

    $ prompt walters

全ての利用可能なテーマをプレビューするには次のコマンドを使って下さい:

    $ prompt -p

### プロンプトのカスタマイズ

上述のプロンプトに満足がいかない（もしくはプロンプトを拡張したい）場合、Zsh にはカスタムプロンプトを作る機能が備わっています。全てのシェルに共通な左側だけのプロンプトに加え、Zsh は左右両側を使うプロンプトをサポートしています。`PROMPT=` と以下の変数を使うことでプロンプトをカスタマイズできます:

#### プロンプト変数

コマンド | 説明 | コメント
--- | --- | ---
一般
`%n` | ユーザー名
`%m` | コンピュータのホスト名 (ドットの前の部分まで)
`%M` | コンピュータのホスト名
`%l` | 現在の tty
`%?` | 最後に実行したアプリケーションのリターンコード
`%#` | ユーザー特権によるプロンプト (root なら `#` その他なら `%`)
時間
`%T` | システム時刻 (HH:MM)
`%*` | システム時刻 (HH:MM:SS)
`%D` | システム日付 (YY-MM-DD)
ディレクトリ
`%d` | カレントディレクトリ。 | 数字を前に付けることでパスの一部だけを表示することが可能です。例えば `%1d` と入力した場合、`/usr/bin` にいるときは `bin` と表示されます。負の値も使えます: `%-1d` は上の例だと `/` と表示されます。
`%~` | カレントディレクトリ。`$HOME` やそのサブディレクトリにいる場合、`$HOME` の部分は `~` に置き換えられます。
整形
`%U [...] %u` | 下線表示の始まりと終わり
`%B [...] %b` | 太字表示の始まりと終わり
`%{ [...] %}` | 表示されない領域。色の設定をするときに使います。このタグによって Zsh はタグの中にあるものを全て無視します。使用しないとプロンプトの縁やインデントに妙な影響が出ることがあります。
カラー
`$fg[color]` | 文字色を設定します (red, green, blue など - 太字デフォルト)。 | Zsh は Bash とは違ったふうに色を設定します。色を使うには `.zshrc` で `PROMPT=` の前に `autoload -U colors && colors` を追加してください。通常、カーソルが動かないように色の設定は `%{ [...] %}` の中に記述します。
`$fg_no_bold[color]` | 太字でない文字色を設定します。
`$fg_bold[color]` | 太字の文字色を設定します。
`$reset_color` | 文字色をデフォルトの色に戻します。

利用できるカラー
`black` | `red`
`green` | `yellow`
`blue` | `magenta`
`cyan` | `white`

Note: 太字の文字色は通常の文字色と必ずしも同じ色になるわけではありません。例えば、`$fg['yellow']` は褐色や濃黄のようになりますが、`$fg_no_bold['yellow']` はやや明るい普通の黄色のようになります。

#### サンプル

以下のようにすることで左右両側にプロンプトを表示できます:

    PROMPT="%{$fg[red]%}%n%{$reset_color%}@%{$fg[blue]%}%m %{$fg_no_bold[yellow]%}%1~ %{$reset_color%}%#"
    RPROMPT="[%{$fg_no_bold[yellow]%}%?%{$reset_color%}]"

次のようになります (色は省略):

    username@host ~ %                                                         [0]

### ディレクトリスタック

Zsh を設定して DIRSTACKSIZE 最後に訪れたフォルダを覚えさせることが可能です。これにより素早く cd することができます。設定ファイルにいくつか設定を加える必要があります:

    .zshrc

    DIRSTACKFILE="$HOME/.cache/zsh/dirs"
    if [[ -f $DIRSTACKFILE ]] && [[ $#dirstack -eq 0 ]]; then
      dirstack=( ${(f)"$(< $DIRSTACKFILE)"} )
      [[ -d $dirstack[1] ]] && cd $dirstack[1]
    fi
    chpwd() {
      print -l $PWD ${(u)dirstack} >$DIRSTACKFILE
    }

    DIRSTACKSIZE=20

    setopt autopushd pushdsilent pushdtohome

    ## Remove duplicate entries
    setopt pushdignoredups

    ## This reverts the +/- operators.
    setopt pushdminus

次のコマンドでディレクトリスタックを表示できます:

    dirs -v

`cd -<NUM>` で訪問済みのフォルダに戻ります。ダッシュの後は自動補完が利用できます。自動補完メニューを使っている場合はとても役に立ちます。

### サンプル .zshrc ファイル

以下は `.zshrc` ファイルのリストです。自由に自分のファイルを追加してください:

- Prezto - Instantly Awesome Zsh (AUR package: prezto-git) is a configuration framework for Zsh. It comes with modules, enriching the command line interface environment with sane defaults, aliases, functions, auto completion, and prompt themes.
- Basic setup, with dynamic prompt and window title/hardinfo => http://github.com/MrElendig/dotfiles-alice/blob/master/.zshrc;
- An Arch package named grml-zsh-config comes from http://grml.org/zsh and provides a zshrc file that includes many tweaks for Zshell.
- https://github.com/slashbeast/things/blob/master/configs/DOTzshrc - zshrc with multiple features, be sure to check out comments into it. Notable features: confirm function to ensure that user wnat to run poweroff, reboot or hibernate, support for GIT in prompt (done without vcsinfo), tab completion with menu, printing current executed command into window's title bar and more.

## 全体設定

Occasionally you might want to have some settings applied globally to all Zsh users. The Zsh wiki tells us that there are some global configuration files, for example `/etc/zshrc`. This however is slightly different on ArchLinux, since it has been compiled with flags specifically to target `/etc/zsh/` instead.

So, for global configuration use `/etc/zsh/zshrc`, not `/etc/zshrc`. The same goes for `/etc/zsh/zshenv`, `/etc/zsh/zlogin` and `/etc/zsh/zlogout`. Note that these files are not installed by default, so you need to create them yourself if you want to use them.

The only exception is zprofile, use `/etc/profile` instead.

### アプリケーションの自動起動

Zsh はいつでも `/etc/zsh/zshenv` と `$ZDOTDIR/.zshenv` を実行します。なのでこれらのファイルをあまり肥大化させないでください。

シェルがログインシェルの場合、`/etc/profile` そして `$ZDOTDIR/.zprofile` からコマンドが読み込まれます。次に、シェルがインタラクティブの場合、`/etc/zsh/zshrc` さらに `$ZDOTDIR/.zshrc` からコマンドが読み込まれます。最後に、シェルがログインシェルの場合、`/etc/zsh/zlogin` ついで `$ZDOTDIR/.zlogin` が読み込まれます。

`man zsh` の STARTUP/SHUTDOWN FILES セクションも参照してください。

## アンインストール

Zsh があなたに合わないと感じて Bash に戻りたいときは、Zsh パッケージを削除する前に必ず、まずデフォルトシェルを変更して下さい。

Warning: Failure to follow the below procedures will result in all kinds of problems: users will no longer have a working shell program.

ターミナルで次のコマンドを root で実行して下さい:

    # chsh -s /bin/bash user

Zsh を使っている全てのユーザーで実行して下さい。

これで安全に Zsh パッケージを削除することができます。

以上を行わなかった場合、root で `/etc/passwd` を編集することで Bash にデフォルトシェルを戻すことができます。

Warning: It is strongly recommended to use `vipw` when editing user information as it prevents badly formatted entries.

例:

編集前:

    username:x:1000:1000:Full Name,,,:/home/username:/bin/zsh

編集後:

    username:x:1000:1000:Full Name,,,:/home/username:/bin/bash

## 参照

- Zsh イントロダクション
- ユーザーガイド
- Zsh ドキュメント (you can choose a different format for the doc in http://zsh.sourceforge.net/Doc/)
- Zsh FAQ
- Zsh wiki
- Zsh-lovers
- Bash2Zsh Reference Card
- Oh My Zshell by Robby Russell
- Gentoo Linux Documentation -- Zsh configuration and installation guide
- Zsh プロンプトの設定

- IRC チャンネル: #zsh at irc.freenode.org

Category:

- Command shells (日本語)