# $Id: PKGBUILD 117869 2014-08-25 12:53:48Z seblu $
# Maintainer: Sébastien "Seblu" Luttringer <seblu@archlinux.org>
# Contributor: Frederik Schwan frederik dot schwan at linux dot com>

pkgname=unifi
pkgver=3.2.1
pkgrel=2
pkgdesc='Centralized management system for Ubiquiti UniFi AP'
arch=('any')
url='https://community.ubnt.com/unifi'
# We are allowed to ship the software in our repository
# https://mailman.archlinux.org/mailman/private/arch-dev/2014-August/015690.html
license=('custom')
depends=('mongodb' 'jre7-openjdk-headless')
makedepends=('jdk7-openjdk')
conflicts=('tomcat-native')
install=unifi.install
source=("UniFi-$pkgver.zip::http://dl.ubnt.com/unifi/$pkgver/UniFi.unix.zip"
        'unifi.service'
        'LICENSE')
md5sums=('9b2d59e6be25db2210f4d85512315e6f'
         '79998cabf110d9a96ba4d3367101c94c'
         '63a6f9e67db6a466f31a40c228c16d63')

package() {
  # lib
  install -dm755 "$pkgdir/usr/lib/unifi"
  cp -r UniFi/{bin,dl,lib,webapps} "$pkgdir/usr/lib/unifi"
  # unjar
  pushd "$pkgdir/usr/lib/unifi/webapps"
  mkdir ROOT
  cd ROOT
  jar -xf ../ROOT.war
  rm ../ROOT.war
  popd

  # data
  install -dm750 "$pkgdir/var/lib/unifi"
  for _d in data run work; do
    install -dm750 "$pkgdir/var/lib/unifi/$_d"
    ln -s "../../../var/lib/unifi/$_d" "$pkgdir/usr/lib/unifi/$_d"
  done
  chown -R 113:113 "$pkgdir/var/lib/unifi"

  # log
  install -dm750 "$pkgdir/var/log/unifi"
  ln -s ../../../var/log/unifi "$pkgdir/usr/lib/unifi/logs"
  chown -R 113:113 "$pkgdir/var/log/unifi"

  # readme
  install -Dm644 UniFi/readme.txt "$pkgdir/usr/share/doc/$pkgname/README"

  # license
  install -Dm644 LICENSE "$pkgdir/usr/share/licenses/$pkgname/LICENSE"

  # systemd
  install -Dm644 unifi.service "$pkgdir/usr/lib/systemd/system/unifi.service"
}

# vim:set ts=2 sw=2 ft=sh et:
