# $Id: PKGBUILD 116587 2014-07-30 15:18:18Z bgyorgy $
# Maintainer: Balló György <ballogyor+arch at gmail dot com>
# Contributor: Dan Serban
# Contributor: Federico Chiacchiaretta

pkgname=transmageddon
pkgver=1.3
pkgrel=1
pkgdesc="Simple python application for transcoding video into formats supported by GStreamer"
arch=('any')
url="http://www.linuxrising.org/"
license=('LGPL')
depends=('python-gobject' 'libnotify' 'gtk3' 'gst-plugins-base')
makedepends=('intltool')
optdepends=('gst-plugins-good: Extra media codecs'
            'gst-plugins-bad: Extra media codecs'
            'gst-plugins-ugly: Extra media codecs'            
            'gst-libav: Extra media codecs'
            'gst-vaapi: Hardware accelerated video encode')
install=$pkgname.install
source=(http://www.linuxrising.org/files/$pkgname-$pkgver.tar.xz)
md5sums=('3476085e3146e8fb5e466f0b0dac742f')

build() {
  cd "$srcdir/$pkgname-$pkgver"

  ./configure --prefix=/usr --sysconfdir=/etc --localstatedir=/var
  make
}

package() {
  cd "$srcdir/$pkgname-$pkgver"

  make DESTDIR="$pkgdir/" install
}
