# $Id: PKGBUILD 116970 2014-08-07 09:50:27Z fyan $
# Maintainer: Felix Yan <felixonmars@gmail.com>

pkgbase=python-sparqlwrapper
pkgname=("python-sparqlwrapper" "python2-sparqlwrapper")
pkgver=1.6.2
pkgrel=1
pkgdesc="SPARQL Endpoint interface to Python"
arch=('any')
url="http://rdflib.github.io/sparqlwrapper/"
license=('W3C')
makedepends=('python-setuptools' 'python2-setuptools')
source=("https://pypi.python.org/packages/source/S/SPARQLWrapper/SPARQLWrapper-$pkgver.tar.gz")
md5sums=('30571c024f5d96b1212a2d757bb90b17')

prepare() {
  cp -r SPARQLWrapper-$pkgver{,-py2}
}

package_python-sparqlwrapper() {
  depends=('python3')

  cd SPARQLWrapper-$pkgver
  python3 setup.py install --root="${pkgdir}" --optimize=1
  #install -Dm644 LICENSE "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
}

package_python2-sparqlwrapper() {
  depends=('python2')

  cd SPARQLWrapper-$pkgver-py2
  python2 setup.py install --root="${pkgdir}" --optimize=1
  #install -Dm644 LICENSE "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
}

