# $Id: PKGBUILD 111453 2014-05-18 21:57:45Z arodseth $
# Maintainer: Alexander Rødseth <rodseth@gmail.com>
# Contributor: Angel 'angvp' Velasquez <angvp[at]archlinux.com.ve>
# Contributor: Stefan Husmann  <stefan-husmann@t-online.de>
# Contributor: Manuel "ekerazha" C. (www.ekerazha.com)

pkgbase=python-configobj
pkgname=('python-configobj' 'python2-configobj')
pkgver=5.0.5
pkgrel=1
pkgdesc='Simple but powerful config file reader and writer for Python'
arch=('any')
url='https://github.com/DiffSK/configobj'
license=('BSD')
makedepends=('python' 'python2')
source=("https://github.com/DiffSK/configobj/archive/v$pkgver.zip")
sha256sums=('674337cf300fdbc274b40df50ee585c51ab4b8cb6c720dd148559f888c0c8a04')

package_python-configobj() {
  depends=('python-six')
  cd "configobj-$pkgver"

  python setup.py install --root="$pkgdir" --optimize=1
  install -Dm644 LICENSE "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
}

package_python2-configobj() {
  depends=('python2-six')
  cd "configobj-$pkgver"

  python2 setup.py install --root="$pkgdir" --optimize=1
  install -Dm644 LICENSE "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
}

# vim:set ts=2 sw=2 et:
