# Maintainer: Florian Pritz <bluewind@xinu.at>

pkgname=perl-term-ui
pkgver=0.42
pkgrel=1
pkgdesc='User interfaces via Term::ReadLine made easy'
arch=(any)
license=(PerlArtistic GPL)
options=(!emptydirs)
depends=(perl)
url=https://metacpan.org/release/Term-UI
source=("http://search.cpan.org/CPAN/authors/id/B/BI/BINGOS/Term-UI-$pkgver.tar.gz")
md5sums=(cc9465134bcb923d65ac1f190d21b04f)
sha512sums=(cf1fc15b1537cc030e8d36a98ca06e31953c57967ae06f1d147f97d01fe9a2c599791b9ab2b7edee0780d244ad0dfb34bf6ee2473849cc24d09853e9c07d02de)
_ddir="Term-UI-$pkgver"

build()
(
  cd "$srcdir/$_ddir"
  export PERL_MM_USE_DEFAULT=1 PERL_AUTOINSTALL=--skipdeps
  unset PERL5LIB PERL_MM_OPT
  /usr/bin/perl Makefile.PL
  make
)

check()
(
  cd "$srcdir/$_ddir"
  export PERL_MM_USE_DEFAULT=1
  unset PERL5LIB
  make test
)

package()
(
  cd "$srcdir/$_ddir"
  make install INSTALLDIRS=vendor DESTDIR="$pkgdir"
  find "$pkgdir" -name .packlist -o -name perllocal.pod -delete
)

# Local Variables:
# mode: shell-script
# sh-basic-offset: 2
# End:
# vim:set ts=2 sw=2 et:
