# $Id: PKGBUILD 101779 2013-11-30 21:44:20Z bgyorgy $
# Maintainer: Balló György <ballogyor+arch at gmail dot com>
# Contributor: Frane Bandov <frane@offbyte.com>
# Contributor: Thijs Vermeir <thijsvermeir@gmail.com>

pkgname=log4net
pkgver=1.2.13
pkgrel=1
pkgdesc="A tool to help the programmer output log statements to a variety of output targets"
arch=('any')
url="http://logging.apache.org/log4net/"
license=('Apache')
depends=('mono')
source=(http://www.apache.org/dist/logging/$pkgname/source/$pkgname-$pkgver-src.zip
        $pkgname.pc)
md5sums=('4f9e22144b2a4dd9c2894f2ce907f3fb'
         'a292da72afbd6bd705e02f4ddb564fd7')

prepare() {
  cd "$srcdir/$pkgname-$pkgver"
  sed -i "s/@VERSION@/$pkgver/" "$srcdir/$pkgname.pc"
}

build() {
  cd "$srcdir/$pkgname-$pkgver"
  mkdir bin
  dmcs -t:library -out:bin/$pkgname.dll -keyfile:$pkgname.snk -d:NET_2_0 \
       -r:System,System.Data,System.Xml,System.Web,System.Net,System.Configuration \
       $(find src -name "*.cs")
}

package() {
  cd "$srcdir/$pkgname-$pkgver"
  gacutil -i bin/$pkgname.dll -package $pkgname-$pkgver -root "$pkgdir/usr/lib/"
  install -Dm644 "$srcdir/$pkgname.pc" "$pkgdir/usr/lib/pkgconfig/$pkgname.pc"
}
