# $Id: PKGBUILD 109905 2014-04-21 14:39:39Z spupykin $
# Maintainer: Sergej Pupykin <pupykin.s+arch@gmail.com>
# Contributor: William Rea <sillywilly@gmail.com>

pkgname=gcstar
pkgver=1.7.0
pkgrel=2
pkgdesc="A collection management application"
arch=('any')
url="http://www.gcstar.org"
license=("GPL")
depends=('gtk2-perl' 'perl-libwww' 'perl-xml-simple'
	 'perl-net-snmp' 'perlxml' 'perl-switch'
	 'perl-xml-libxml' 'perl-sort-naturally'
	 'perl-http-message' 'perl-http-date' 'perl-http-cookies'
	 'perl-gd' 'perl-date-calc'
	 'perl-archive-zip' 'perl-datetime-format-strptime'
	 'perl-gdgraph' 'perl-mp3-info')
# 'perl-ogg-vorbis-header-pureperl' 'perl-mp3-tag'
source=(http://download.gna.org/gcstar/gcstar-$pkgver.tar.gz)
md5sums=('94d0c4d6acc912b4b4d3a72d934cc16d')

package() {
  cd $srcdir/gcstar
  ./install  --prefix=$pkgdir/usr
  install -D -m644 $pkgdir/usr/share/gcstar/icons/gcstar_256x256.png \
                   $pkgdir/usr/share/pixmaps/gcstar.png
  install -D -m644 $pkgdir/usr/share/gcstar/icons/gcstar_32x32.png \
                   $pkgdir/usr/share/pixmaps/gcstar32.png
  cp -R share/applications $pkgdir/usr/share
  mv $pkgdir/usr/man $pkgdir/usr/share
}
