# $Id: PKGBUILD 113963 2014-07-01 10:49:37Z spupykin $
# Maintainer: Sergej Pupykin <pupykin.s+arch@gmail.com>
# Contributor: Andrea Scarpino <andrea@archlinux.org>
# Contributor: Javier 'Phrodo_00' Aravena <phrodo.00@gmail.com>
# Maintainer: Daniel J Griffiths <ghost1227@archlinux.us>

pkgname=devede
pkgver=3.23.0
pkgrel=2
pkgdesc="A program to create VideoDVDs and CDs"
arch=('any')
url="http://www.rastersoft.com/programas/devede.html"
license=('GPL3')
depends=('mplayer' 'mencoder' 'ffmpeg' 'dvdauthor' 'vcdimager'
	 'cdrkit' 'pygtk' 'ttf-dejavu' 'dbus-python')
source=(http://www.rastersoft.com/descargas/${pkgname}-${pkgver}.tar.bz2)
md5sums=('c6c012630bb2492b1c9146c727681963')

build() {
  cd ${srcdir}/${pkgname}-$pkgver
  # python2 fix
  for file in devede *.py; do
    sed -i 's_#!/usr/bin/env python_#!/usr/bin/env python2_' $file
  done
}

package() {
  cd ${srcdir}/${pkgname}-$pkgver
  ./install.sh --DESTDIR=${pkgdir} \
	--prefix=/usr \
	--unistall=no \
	--targeted=yes
  install -D -m644 ${pkgname}.desktop ${pkgdir}/usr/share/applications/${pkgname}.desktop
}
