# $Id: PKGBUILD 200262 2013-11-24 04:14:46Z bisson $
# Maintainer: Gaetan Bisson <bisson@archlinux.org>
# Contributor: Firmicus <francois.archlinux.org>
# Contributor: dorphell <dorphell@archlinux.org>

pkgname=gsfonts
_realname=urw-fonts
pkgver=1.0.7pre44
_fedoraver=2.4
_fedorarel=18.fc21
pkgrel=4
pkgdesc='Standard Ghostscript Type1 fonts from URW'
url='http://sourceforge.net/projects/gs-fonts/'
arch=('any')
license=('GPL2')
makedepends=('rpmextract')
depends=('xorg-font-utils' 'fontconfig')
source=("http://kojipkgs.fedoraproject.org/packages/${_realname}/${_fedoraver}/${_fedorarel}/src/${_realname}-${_fedoraver}-${_fedorarel}.src.rpm")
sha1sums=('fafb435a5bce2c6b9746c05959bd8d137e00f9c3')

provides=("${_realname}")
install=install

prepare() {
	cd "${srcdir}"
	rpmextract.sh "${_realname}-${_fedoraver}-${_fedorarel}.src.rpm"
	bsdtar xf *.tar.bz2
}

package() {
	cd "${srcdir}"
	install -d "${pkgdir}"/usr/share/fonts/Type1
	install -m644 *.{pfb,pfm,afm} "${pkgdir}"/usr/share/fonts/Type1
}
