# $Id: PKGBUILD 108485 2014-03-27 14:48:16Z fyan $
# Maintainer: Felix Yan <felixonmars@gmail.com>
# Contributor: Stéphane Gaudreault <stephane@archlinux.org>

pkgbase=python-pytools
pkgname=('python2-pytools' 'python-pytools')
pkgver=2014.1.2
pkgrel=2
pkgdesc="A collection of tools for Python"
arch=('any')
url="http://mathema.tician.de/software/pytools"
license=('MIT')
makedepends=('python2-setuptools' 'python-setuptools')
source=(http://pypi.python.org/packages/source/p/pytools/pytools-${pkgver}.tar.gz)

build() {
   cp -a pytools-${pkgver}{,-python2}

   cd "$srcdir/pytools-${pkgver}"
   python setup.py build

   cd "${srcdir}/pytools-${pkgver}-python2"
   python2 setup.py build
}

package_python2-pytools() {
   depends=('python2' 'python2-decorator')
   cd "${srcdir}/pytools-${pkgver}-python2"
   python2 setup.py install --prefix=/usr --root="${pkgdir}" --skip-build --optimize=1
}

package_python-pytools(){
   depends=('python' 'python-decorator')
   cd "${srcdir}/pytools-${pkgver}"
   python setup.py install --prefix=/usr --root="${pkgdir}" --skip-build --optimize=1
}

sha512sums=('4c849518223a8257282a448554d38fee44b9583b1567b8f606a7903994d32274c5f67addfe629ea45a73587efaf9a826604c3688147b10914657d692ed9039e6')
