# $Id: PKGBUILD 109080 2014-04-10 09:24:32Z fyan $
# Maintainer: Felix Yan <felixonmars@gmail.com>
# Contributor: Ismael Carnales <icarnales at gmail dot com>
# Contributor: Sergey Mastykov <smastykov[at]gmail[dot]com>

pkgbase=pep8
pkgname=("$pkgbase" "$pkgbase-python2")
pkgver=1.5.5
pkgrel=1
pkgdesc="Python style guide checker"
arch=('any')
url="http://github.com/jcrocholl/pep8/"
license=('custom:Expat')
makedepends=('python-setuptools' 'python2-setuptools' 'git')
source=("git+https://github.com/jcrocholl/${pkgbase}.git#tag=$pkgver")
sha256sums=('SKIP')

prepare() {
  cp -r $pkgbase{,-py2}

  sed -i '1s/env python$/python2/' $pkgbase-py2/pep8.py
}

build() {
  cd "${srcdir}/${pkgbase}"
  python setup.py build

  cd "${srcdir}/${pkgbase}-py2"
  python2 setup.py build
}

check() {
  cd "${srcdir}/${pkgbase}"
  python setup.py test

  cd "${srcdir}/${pkgbase}-py2"
  python2 setup.py test
}

package_pep8() {
  depends=('python' 'python-setuptools')
  provides=('pep8-python3')
  conflicts=('pep8-python3')
  replaces=('pep8-python3')

  cd $pkgbase
  python3 setup.py install -O1 --prefix=/usr --root="$pkgdir/"

  install -Dm644 LICENSE "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
}

package_pep8-python2() {
  depends=('python2' 'python2-setuptools')
  
  cd $pkgbase-py2
  python2 setup.py install -O1 --prefix=/usr --root="$pkgdir/"
  mv "$pkgdir/usr/bin/pep8" "$pkgdir/usr/bin/pep8-python2"

  install -Dm644 LICENSE "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
}

# vim:set ts=2 sw=2 et:
