# $Id: PKGBUILD 108403 2014-03-27 14:47:13Z fyan $
# Maintainer: Evangelos Foutras <evangelos@foutrelis.com>
# Contributor: Ionut Biru <ibiru@archlinux.org>
# Contributor: Allan McRae <allan@archlinux.org>
# Contributor: FJ <joostef@gmail.com>
# Contributor: Sebastien Piccand <sebcactus gmail com>

pkgname=gaupol
pkgver=0.25
pkgrel=2
pkgdesc="An editor for text-based subtitles"
arch=('any')
url="http://home.gna.org/gaupol"
license=('GPL')
depends=('python-gobject' 'gtk3' 'gst-plugins-base' 'gst-plugins-good'
         'iso-codes' 'desktop-file-utils' 'hicolor-icon-theme')
makedepends=('intltool')
optdepends=('python-pyenchant: spell-checking'
            'gtkspell3: inline spell-checking'
            'python-chardet: character encoding auto-detection'
            'mplayer: subtitle preview'
            'vlc: subtitle preview'
            'gst-plugins-bad: extra media codecs'
            'gst-plugins-ugly: extra media codecs'
            'gst-libav: extra media codecs')
install=gaupol.install
source=(http://download.gna.org/$pkgname/0.25/$pkgname-$pkgver.tar.xz)
sha256sums=('6398035397355db52f80317fde0bbe81470601c9cf6b8825bd0a84a5115cb053')

package() {
  cd "$srcdir/$pkgname-$pkgver"

  python3 setup.py --without-iso-codes install --root="$pkgdir" -O1
}

# vim:set ts=2 sw=2 et:
