# $Id: PKGBUILD 191359 2013-07-23 23:38:48Z eric $
# Maintainer: Eric Bélanger <eric@archlinux.org>

pkgbase=quodlibet
pkgname=('quodlibet' 'quodlibet-plugins')
pkgver=3.0.2
pkgrel=1
arch=('any')
license=('GPL2')
url="http://code.google.com/p/quodlibet/"
makedepends=('python2' 'intltool')
options=('!makeflags')
source=(https://quodlibet.googlecode.com/files/$pkgbase-$pkgver.tar.gz
        https://quodlibet.googlecode.com/files/$pkgbase-plugins-$pkgver.tar.gz)
sha1sums=('d86fcd5ae461398891ad08b23d4497c3cfe0587d'
          '8126fc4c69fd7db556a1ff38d9b41f27d6ad7264')

prepare() {
  cd ${pkgbase}-${pkgver}
  sed -i 's/env python/env python2/' exfalso.py quodlibet.py \
    ../${pkgbase}-plugins-${pkgver}/songsmenu/replaygain.py
  sed -i 's|/usr/bin/python|/usr/bin/python2|' operon.py 
}

build() {
  cd ${pkgbase}-${pkgver}
  python2 setup.py build
}

package_quodlibet() {
  pkgdesc="An audio library tagger, manager and player"
  depends=('gtk3' 'python2-gobject' 'python2-dbus' 'mutagen' 
           'gst-plugins-base' 'gst-plugins-good' 'gst-plugins-ugly' 
	   'gnome-icon-theme')
  optdepends=('gst-libav: for ffmpeg (ASF/WMA) support'
              'gst-plugins-bad: for Musepack support'
              'libgpod: for ipod support'
              'python2-feedparser: for audio feeds (podcast) support'
              'libkeybinder3: for the multimedia keys support'
              'media-player-info: for media devices support')
  install=quodlibet.install

  cd ${pkgbase}-${pkgver}
  python2 setup.py install --prefix="${pkgdir}/usr"
}

package_quodlibet-plugins() {
  pkgdesc="Various plugins for QuodLibet"
  depends=('quodlibet')
  optdepends=('cddb-py: for "CDDB Lookup" plugin'
              'python2-musicbrainz2: for "MusicBrainz Lookup" plugin'
              'python2-pyinotify: for "Automatic library update" plugin'
	      'kakasi: for "Kana/Kanji Simple Inverter" plugin'
	      'zeitgeist: for "Event Logging" plugin'
              'gst-plugins-bad: for "Audio Pitch/Speed" plugin')

  cd ${pkgbase}-plugins-${pkgver}
  install -d "${pkgdir}/usr/lib/python2.7/site-packages/quodlibet/plugins"
  cp -r editing events gstreamer playorder songsmenu "${pkgdir}/usr/lib/python2.7/site-packages/quodlibet/plugins"
}
