# $Id: PKGBUILD 205029 2014-02-03 10:47:53Z bpiotrowski $
# Maintainer: Jan de Groot <jgc@archlinux.org>

pkgname=bcprov
pkgver=1.50
pkgrel=1
pkgdesc="Java cryptography APIs (Bouncy Castle)"
arch=('any')
url="http://www.bouncycastle.org/java.html"
license=('custom')
depends=('java-runtime')
makedepends=('java-environment' 'junit')
source=("http://www.bouncycastle.org/download/bcprov-jdk15on-${pkgver/./}.tar.gz")
md5sums=('9c949462f8ae1efd2bd12e032f3fb5b5')

build() {
  cd "${srcdir}/bcprov-jdk15on-${pkgver/./}"
  jar xf src.zip

  mkdir classes
  find . -name '*.java' > src.list
  javac -encoding ISO-8859-1 -cp /usr/share/java/junit.jar -d classes @src.list

  cd classes
  find . -path '*test/*.class' -delete
  find . -depth -type d -empty -delete
  install -m644 ../org/bouncycastle/x509/*.properties org/bouncycastle/x509/
  jar cf ../bcprov.jar *
}

package() {
  cd "${srcdir}/bcprov-jdk15on-${pkgver/./}"
  install -m755 -d "${pkgdir}/usr/share/java"
  install -m755 -d "${pkgdir}/usr/share/licenses/${pkgname}"
  install -m644 bcprov.jar "${pkgdir}/usr/share/java/"
  install -m644 LICENSE.html "${pkgdir}/usr/share/licenses/${pkgname}/"
}
