This reference is for Processing 2.0+. If you have a previous version, use the reference included with your software. If you see any errors or have suggestions, please let us know. If you prefer a more technical reference, visit the Processing Javadoc.

Name | ### return
Examples |
    int val = 30;

    void draw() {
      int t = timestwo(val);
      println(t);
    }

    // The first 'int' in the function declaration
    // specifies the type of data to be returned.
    int timestwo(int dVal) {
      dVal = dVal * 2;
      return dVal;  // Returns an int of 60, in this case
    }
    int[] vals = {10, 20, 30};

    void draw() {
      int[] t = timestwo(vals);
      println(t);
      noLoop();
    }

    int[] timestwo(int[] dVals) {
      for (int i = 0; i < dVals.length; i++) {
        dVals[i] = dVals[i] * 2;
      }
      return dVals;  // Returns an array of 3 ints: 20, 40, 60
    }
    void draw() {
      background(204);
      line(0, 0, width, height);
      if (mousePressed) {
        return;  // Break out of draw(), skipping the line statement below
      }
      line(0, height, width, 0);  // Executed only if mouse is not pressed
    }
Description | Keyword used to indicate the value to return from a function. The value being returned must be the same datatype as defined in the function declaration. Functions declared with void can't return values and shouldn't include a return value. The keyword return may also be used to break out of a function, thus not allowing the program to the remaining statements. (See the third example above.)
Syntax |
    type function {
      statements
      return value
    }
Parameters |
type | boolean, byte, char, int, float, String, boolean[], byte[], char[], int[], float[], or String[]
function | the function that is being defined
statements | any valid statements
value | must be the same datatype as the "type" parameter

Updated on October 26, 2013 08:58:35pm PDT