$Id: PKGBUILD 96942 2013-09-09 01:59:35Z dwallace $
# Maintainer: Daniel Wallace < danielwallace at gtmanfred dot com>
# Contributor: Trizen <echo dHJpemVueEBnbWFpbC5jb20K | base64 -d>

pkgname=youtube-viewer
_pkgdir=trizen-youtube-viewer
epoch=1
pkgver=3.0.8
pkgrel=1
pkgdesc="A command line utility for viewing youtube-videos in MPlayer."
arch=('any')
url="https://github.com/trizen/youtube-viewer"
license=('GPL3')
source=("$pkgname-$pkgver.zip::https://github.com/trizen/$pkgname/zipball/$pkgver")
sha256sums=('b53e84da4b51b414f7eb5b2d93b43237d0a67d831ca753f21812f060dd8960d9')

depends=('perl>=5.10.0' 'perl-data-dump' 'perl-libwww' 'perl-xml-fast')
optdepends=('vlc: for playing videos'
			'mplayer: for playing videos'
			'perl-term-readkey: to get the terminal width size'
            'perl-term-readline-gnu: for a better STDIN support'
            'perl-lwp-protocol-https: for login and https support'
            'gcap: for retrieving Youtube closed captions. [in AUR]')


build() {
    cd "$srcdir/$_pkgdir"*/WWW-YoutubeViewer

    perl Build.PL   # --gtk-youtube-viewer
}

check(){
    cd "$srcdir/$_pkgdir"*/WWW-YoutubeViewer

    ./Build test
}

package() {
    cd "$srcdir/$_pkgdir"*/WWW-YoutubeViewer

    ./Build install --install_path script=/usr/bin --destdir=$pkgdir
    rm -r "$pkgdir/usr/lib/"

}
