# Packager: Justin Davis <jrcd83@gmail.com>
# $Id: PKGBUILD 86616 2013-03-20 17:21:59Z eric $

pkgname=perl-io-all
pkgver=0.46
pkgrel=1
pkgdesc="IO::All of it to Graham and Damian!"
arch=(any)
license=(PerlArtistic GPL)
options=(!emptydirs)
depends=('perl>=5.6.1' 'perl-io-string>=1.08')
url="https://metacpan.org/release/IO-All"
source=("http://search.cpan.org/CPAN/authors/id/I/IN/INGY/IO-All-${pkgver}.tar.gz")
sha1sums=('1292fd897178f79f4a40555bffc89eb645d3f02a')
_distdir="${srcdir}/IO-All-${pkgver}"

build()
(
    export PERL_MM_USE_DEFAULT=1 PERL5LIB=""                 \
      PERL_AUTOINSTALL=--skipdeps                            \
      PERL_MM_OPT="INSTALLDIRS=vendor"     \
      PERL_MB_OPT="--installdirs vendor" \
      MODULEBUILDRC=/dev/null

    cd "$_distdir"
    /usr/bin/perl Makefile.PL
    make
)

check()
(
    export PERL_MM_USE_DEFAULT=1 PERL5LIB=""
    cd "$_distdir"
    make test
)

package() {
    cd "$_distdir"
    make DESTDIR="$pkgdir" install
}

# Local Variables:
# mode: shell-script
# sh-basic-offset: 2
# End:
# vim:set ts=2 sw=2 et:
