# $Id: PKGBUILD 97263 2013-09-15 21:50:11Z svenstaro $
# Maintainer: Sven-Hendrik Haase <sh@lutzhaase.com>
# Contributor: Matthew Bowra-Dean <matthew@ijw.co.nz>
pkgname=openra
pkgver=20130915
pkgrel=1
pkgdesc="An open-source implementation of the Red Alert engine using .NET/mono and OpenGL"
arch=('any')
url="http://open-ra.org"
license=('GPL3')
install=openra.install
depends=('mono' 'openal' 'libgl' 'freetype2' 'sdl' 'hicolor-icon-theme' 'ttf-dejavu' 'gtk-update-icon-cache' 'desktop-file-utils')
makedepends=('git' 'unzip')
optdepends=('nvidia-cg-toolkit: for using the alternative Cg renderer')
options=(!strip)
source=("openra-$pkgver::https://github.com/OpenRA/OpenRA/tarball/release-$pkgver"
        https://github.com/OpenRA/OpenRA/pull/3837.patch)
md5sums=('9284b6113a77978f446fa0bade7f9cd3'
         '46ee544f4117c80cc400c03e1637f1f1')

build() {
  cd OpenRA-OpenRA-*

  patch -Np1 < $srcdir/3837.patch
  make
}

package() {
  cd OpenRA-OpenRA-*

  mkdir -p "$pkgdir/usr/share/applications"
  sed "s/{VERSION}/$pkgver/g" packaging/linux/openra.desktop > "$pkgdir/usr/share/applications/openra.desktop"

  sed "/Version/s/{DEV_VERSION}/release-${pkgver}/" -i mods/{ra,cnc}/mod.yaml  

  mkdir -p "$pkgdir/usr/share/icons/"
  cp -r packaging/linux/hicolor "$pkgdir/usr/share/icons/"

  make prefix=/usr DESTDIR="$pkgdir" install

  find "$pkgdir" -iname \*.mdb -delete
}
