# $Id: PKGBUILD 91939 2013-05-30 07:36:37Z mtorromeo $
# Maintainer: Massimiliano Torromeo <massimiliano.torromeo@gmail.com>
# Contributor: Pierre Schmitz <pierre@archlinux.de>

pkgname=openfire
pkgver=3.8.2
pkgrel=1
pkgdesc="High performance XMPP (Jabber) server."
arch=('any')
url='http://www.igniterealtime.org/projects/openfire/'
license=('GPL')
depends=('java-runtime-headless')
makedepends=('apache-ant')
install='openfire.install'
backup=(
	'etc/openfire/openfire.xml' 'etc/openfire/openfire.xml' 'etc/openfire/openfire.xml' \
	'etc/conf.d/openfire' 'etc/openfire/security/keystore' 'etc/openfire/security/truststore' \
	'etc/openfire/security/client.truststore')
source=("http://www.igniterealtime.org/downloadServlet?filename=openfire/openfire_src_${pkgver//./_}.tar.gz" \
	'openfire.conf' 'openfire.service')

build() {
	cd "$srcdir/openfire_src/build"
	rm -rf ../src/resources/nativeAuth/
	ant openfire
# 	ant plugins
}

package() {
	cd "$srcdir/openfire_src/target/openfire"

	install -dm755 "$pkgdir/usr/lib" "$pkgdir/usr/share/openfire/resources"
	install -dm750 "$pkgdir/etc/openfire" "$pkgdir/var/log/openfire"

	install -Dm644 "$srcdir/openfire.conf" "$pkgdir/etc/conf.d/openfire"
	install -Dm644 "$srcdir/openfire.service" "$pkgdir/usr/lib/systemd/system/openfire.service"

	rm -rf bin logs

	cp -R conf/* "$pkgdir/etc/openfire/"
	ln -s /etc/openfire "$pkgdir/usr/share/openfire/conf"

	cp -R resources/security "$pkgdir/etc/openfire/"
	ln -s /etc/openfire/security "$pkgdir/usr/share/openfire/resources/security"

	cp -R plugins "$pkgdir/usr/share/openfire/"
	cp -R resources/{database,spank} "$pkgdir/usr/share/openfire/resources/"
	cp -R lib "$pkgdir/usr/lib/openfire"
}

sha256sums=('2d1bf97523eafe9485a013bbb70ff282d41470f65b842f4d7656c9788ab96c8d'
            'c8a612abee90bdc9a2869e562a4bbbf596159c60adcd23368833a0e2ca27c1d4'
            '772332b66a90935ddb8075eb10eab9b95a84caa45908bb3fa5861d7fa148399c')
