# $Id: PKGBUILD 92239 2013-06-03 08:54:09Z heftig $
# Maintainer: Jan Alexander Steffens (heftig) <jan.steffens@gmail.com>
# Contributor: FaziBear <fazibear@gmail.com>

pkgname=jruby
pkgver=1.7.4
pkgrel=2
pkgdesc="100% pure-Java implementation of the Ruby programming language"
arch=(any)
url="http://www.jruby.org/"
license=(EPL GPL2 LGPL2.1 custom)
depends=(java-runtime-headless bash)
options=(!strip)
source=(http://jruby.org.s3.amazonaws.com/downloads/$pkgver/$pkgname-bin-${pkgver}.tar.gz)
sha256sums=('ef6dead787780f18a43758003689fd9ba40e64abc04cd41a6ff1eaf1557dfa69')

build() {
  cd jruby-$pkgver/tool/nailgun
  ./configure
  make
}


package() {
  cd "$pkgdir"

  mkdir opt
  tar -C opt -xf "$srcdir/$pkgname-bin-$pkgver.tar.gz"
  mv opt/jruby-$pkgver opt/jruby

  find opt/jruby -regextype posix-extended -regex '.*\.(bat|dll|exe)' -delete
  rm -r opt/jruby/lib/native/{Darwin,*-SunOS,*-Windows,*-AIX,*-FreeBSD}

  install "$srcdir/$pkgname-$pkgver/tool/nailgun/ng" opt/jruby/tool/nailgun/ng

  mkdir -p usr/bin
  for _file in jirb{,_swing} jruby{,c} jgem; do
    ln -s ../../opt/jruby/bin/$_file usr/bin/$_file
  done

  mkdir -p usr/share/licenses/$pkgname
  ln -s ../../../../opt/jruby/COPYING usr/share/licenses/$pkgname/COPYING
}
